aws_deployment_role_credential

注記

このリソースの API は、ユーザーエクスペリエンスを簡素化するために、将来のバージョンで変更される可能性があります。

VPC でのデプロイを成功させるためには、AWS デプロイメントクレデンシャルを作成する必要があります。詳細については、 Create an AWS deployment credential を参照してください。

このリソースは、以下のリソースと celerdatabyoc_aws_data_credential_assume_policy データソースに依存しています。

• celerdatabyoc_aws_data_credential_policy
• aws_iam_role (data credential role)
• celerdatabyoc_aws_deployment_credential_policy
• celerdatabyoc_aws_deployment_credential_assume_policy
• aws_iam_role (deployment_credential_role)

これらのリソースを設定した後で、このリソースを実装することができます。

使用例

resource "celerdatabyoc_aws_data_credential_policy" "new" {
   bucket = local.s3_bucket
}

data "celerdatabyoc_aws_data_credential_assume_policy" "assume_role" {}

resource "aws_iam_role" "celerdata_data_cred_role" {
  name               = "<celerdata_data_credential_role_name>"
  assume_role_policy = data.celerdatabyoc_aws_data_credential_assume_policy.assume_role.json
  description        = "<celerdata_data_credential_role_description>"
  inline_policy {
    name   = "<celerdata_data_credential_role_policy_name>"
    policy = celerdatabyoc_aws_data_credential_policy.role_policy.json
  }
}

resource "celerdatabyoc_aws_deployment_credential_policy" "role_policy" {
  bucket = local.s3_bucket
  data_role_arn = aws_iam_role.celerdata_data_cred_role.arn 
}

resource "celerdatabyoc_aws_deployment_credential_assume_policy" "role_policy" {}

resource "aws_iam_role" "deploy_cred_role" {
  name               = "<celerdata_deployment_credential_role_name>"
  assume_role_policy = celerdatabyoc_aws_deployment_credential_assume_policy.role_policy.json
  description        = "<celerdata_deployment_credential_role_description>"
  inline_policy {
    name   = "<celerdata_deployment_credential_role_policy_name>"
    policy = celerdatabyoc_aws_deployment_credential_policy.role_policy.json
  }
}

resource "celerdatabyoc_aws_deployment_role_credential" "deployment_role_credential" {
  name = "<celerdata_deployment_credential_name>"
  role_arn = aws_iam_role.deploy_cred_role.arn
  external_id = celerdatabyoc_aws_deployment_credential_assume_policy.role_policy.external_id
  policy_version = celerdatabyoc_aws_deployment_credential_policy.role_policy.version
}

引数リファレンス

注記

このセクションでは、celerdatabyoc_aws_deployment_role_credential リソースの引数のみを説明します。他のリソースの引数については、対応するリソースのトピックを参照してください。

このリソースには、以下の必須引数とオプション引数があります。

必須:

• role_arn: （新しいリソースを強制）デプロイメントクレデンシャルで参照されるクロスアカウント IAM ロールの ARN。値を aws_iam_role.deploy_cred_role.arn に設定します。

• external_id: （新しいリソースを強制）デプロイメントクレデンシャルで参照されるクロスアカウント IAM ロールを作成するために使用される外部 ID。値を celerdatabyoc_aws_deployment_credential_assume_policy.role_policy.external_id に設定します。

• policy_version: ポリシーのバージョン。値を celerdatabyoc_aws_deployment_credential_policy.role_policy.version に設定します。

オプション:

• name: （新しいリソースを強制）デプロイメントクレデンシャルの名前。一意の名前を入力します。省略した場合、Terraform はランダムで一意の名前を割り当てます。

属性リファレンス

このリソースは、以下の属性をエクスポートします。

• id: デプロイメントクレデンシャルの ID。

参照

• celerdatabyoc_aws_deployment_credential_policy
• celerdatabyoc_aws_deployment_credential_assume_policy
• aws_iam_role